¿Cómo Guardar Cada Página Como Archivos PDF Separados En Un Documento De Word?

 

¿Cómo Guardar Cada Página Como Archivos PDF Separados En Un Documento De Word?

Mientras usa un documento de Microsoft Word, puede guardar cada página como archivos PDF separados uno por uno con su función Guardar como incorporada. Sin embargo, si hay cientos de páginas que deben dividirse y guardarse como archivos PDF individuales, ¿cómo puede hacerlo? Este artículo proporciona un método para que pueda resolver rápidamente este problema.

Guarde cada página como archivos pdf separados a granel con código VBA

---

 Guarde Cada Página Como Archivos Pdf Separados A Granel Con Código VBA

El siguiente código VBA le ayuda a guardar rápidamente cada página en un documento como archivos PDF individuales al mismo tiempo. Haz lo siguiente.

1. Abra el documento, guardará cada página o páginas específicas como archivos pdf, luego presione el otro + F11 teclas para abrir el Microsoft Visual Basic para aplicaciones ventana.

2. En el Microsoft Visual Basic para aplicaciones ventana, haga clic recuadro > Módulo, copie debajo del código VBA en la ventana del módulo.

Código VBA: guarde cada página como archivos pdf separados al mismo tiempo en un documento de Word

Sub SaveAsSeparatePDFs()
'Updated by Extendoffice 20180906
    Dim I As Long
    Dim xStr As String
    Dim xPathStr As Variant
    Dim xDictoryStr As String
    Dim xFileDlg As FileDialog
    Dim xStartPage, xEndPage As Long
    Dim xStartPageStr, xEndPageStr As String
    Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)
    If xFileDlg.Show <> -1 Then
        MsgBox "Please chose a valid directory", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    xPathStr = xFileDlg.SelectedItems(1)
    xStartPageStr = InputBox("Begin saving PDFs starting with page __? " & vbNewLine & "(ex: 1)", "Kutools for Word")
    xEndPageStr = InputBox("Save PDFs until page __?" & vbNewLine & "(ex: 7)", "Kutools for Word")
    If Not (IsNumeric(xStartPageStr) And IsNumeric(xEndPageStr)) Then
        MsgBox "The enterng start page and end page should be number format", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    xStartPage = CInt(xStartPageStr)
    xEndPage = CInt(xEndPageStr)
    If xStartPage > xEndPage Then
        MsgBox "The start page number can't be larger than end page", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    If xEndPage > ActiveDocument.BuiltInDocumentProperties(wdPropertyPages) Then
        xEndPage = ActiveDocument.BuiltInDocumentProperties(wdPropertyPages)
    End If
    For I = xStartPage To xEndPage
        ActiveDocument.ExportAsFixedFormat xPathStr & "\Page_" & I & ".pdf", _
        wdExportFormatPDF, False, wdExportOptimizeForPrint, wdExportFromTo, I, I, wdExportDocumentWithMarkup, _
        False, False, wdExportCreateHeadingBookmarks, True, False, False
    Next
End Sub

3. presione el F5 clave para ejecutar el código.

4. En el Búsqueda de ventana, seleccione una carpeta para guardar los archivos pdf y haga clic en el OK botón. Ver captura de pantalla:

5. En el primero Kutools for Word cuadro de diálogo, ingrese el número de página de inicio de su documento en el cuadro de texto y haga clic en OK.

6. En el segundo Kutools for Word cuadro de diálogo, ingrese el número de la última página de su documento, luego haga clic en DE ACUERDO. Ver captura de pantalla:

Nota:: Si solo desea guardar varias páginas continuas en el documento como archivos PDF separados, como las páginas 4, 5 y 6, ingrese 4 y 6 por separado en los dos cuadros de diálogo anteriores.

Después de ejecutar el código, vaya a la carpeta especificada que seleccionó en el paso 4, puede ver que todas las páginas están divididas y guardadas como archivos PDF individuales como se muestra a continuación.